Cara Menciptakan Start Stop Status Nt Services Vb6

12 views
Pada kesempatan postingan artikel kali ini admin akan membahas wacana NT Service yang terdapat pada sistem operasi windows dan aneka macam macamnya, bahkan file service bawaan dari instalasi Sistem Operasi Windows atau Service dari aplikasi yang kita instal. Klik Start sajian Windows – RUN kemudian ketik services.msc kemudian Enter atau klik OK, maka tampil sebuah jendela service dan disitulah semua aplikasi yang run memakai file service.
Sourcode kali ini wacana bagaimana cara Start, Stop dan Status dari salah satu service yang ada diwindows. Buatlah sebuah project kemudian form, module serta tambahkan 2 buah CommandButton, Label dan TexBoxt menyerupai tampilan dibawah ini : 


Designlah komponen-komponen Label, TextBox dan CommandButton pada form sebagus mungkin selanjutnya copikan syntak dibawah ini ke dalam Module

Public Const SERVICES_ACTIVE_DATABASE = “ServicesActive”
Public Const SERVICE_CONTROL_STOP = &H1
Public Const SERVICE_CONTROL_PAUSE = &H2

Public Const SERVICE_STOPPED = &H1
Public Const SERVICE_START_PENDING = &H2
Public Const SERVICE_STOP_PENDING = &H3
Public Const SERVICE_RUNNING = &H4
Public Const SERVICE_CONTINUE_PENDING = &H5
Public Const SERVICE_PAUSE_PENDING = &H6
Public Const SERVICE_PAUSED = &H7

Public Const STANDARD_RIGHTS_REQUIRED = &HF0000
Public Const SC_MANAGER_CONNECT = &H1
Public Const SC_MANAGER_CREATE_SERVICE = &H2
Public Const SC_MANAGER_ENUMERATE_SERVICE = &H4
Public Const SC_MANAGER_LOCK = &H8
Public Const SC_MANAGER_QUERY_LOCK_STATUS = &H10
Public Const SC_MANAGER_MODIFY_BOOT_CONFIG = &H20
Public Const SC_MANAGER_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED Or SC_MANAGER_CONNECT Or SC_MANAGER_CREATE_SERVICE Or SC_MANAGER_ENUMERATE_SERVICE Or SC_MANAGER_LOCK Or SC_MANAGER_QUERY_LOCK_STATUS Or SC_MANAGER_MODIFY_BOOT_CONFIG)

Public Const SERVICE_QUERY_CONFIG = &H1
Public Const SERVICE_CHANGE_CONFIG = &H2
Public Const SERVICE_QUERY_STATUS = &H4
Public Const SERVICE_ENUMERATE_DEPENDENTS = &H8
Public Const SERVICE_START = &H10
Public Const SERVICE_STOP = &H20
Public Const SERVICE_PAUSE_CONTINUE = &H40
Public Const SERVICE_INTERROGATE = &H80
Public Const SERVICE_USER_DEFINED_CONTROL = &H100
Public Const SERVICE_ALL_ACCESS = (STANDARD_RIGHTS_REQUIRED Or SERVICE_QUERY_CONFIG Or SERVICE_CHANGE_CONFIG Or SERVICE_QUERY_STATUS Or SERVICE_ENUMERATE_DEPENDENTS Or SERVICE_START Or SERVICE_STOP Or SERVICE_PAUSE_CONTINUE Or SERVICE_INTERROGATE Or SERVICE_USER_DEFINED_CONTROL)

Type SERVICE_STATUS
    dwServiceType As Long
    dwCurrentState As Long
    dwControlsAccepted As Long
    dwWin32ExitCode As Long
    dwServiceSpecificExitCode As Long
    dwCheckPoint As Long
    dwWaitHint As Long
End Type

Declare Function CloseServiceHandle Lib “advapi32.dll” (ByVal hSCObject As Long) As Long

Declare Function ControlService Lib “advapi32.dll” (ByVal hService As Long, ByVal dwControl As Long, lpServiceStatus As SERVICE_STATUS) As Long 

Declare Function OpenSCManager Lib “advapi32.dll” Alias “OpenSCManagerA” (ByVal lpMachineName As String, ByVal lpDatabaseName As String, ByVal dwDesiredAccess As Long) As Long  

Declare Function OpenService Lib “advapi32.dll” Alias “OpenServiceA” (ByVal hSCManager As Long, ByVal lpServiceName As String, ByVal dwDesiredAccess As Long) As Long  

Declare Function QueryServiceStatus Lib “advapi32.dll” (ByVal hService As Long, lpServiceStatus As SERVICE_STATUS) As Long  

Declare Function StartService Lib “advapi32.dll” Alias “StartServiceA” (ByVal hService As Long, ByVal dwNumServiceArgs As Long, ByVal lpServiceArgVectors As Long) As Long

Public Function ServiceStatus(ComputerName As String, ServiceName As String) As String
    Dim ServiceStat As SERVICE_STATUS
    Dim hSManager As Long
    Dim hService As Long
    Dim hServiceStatus As Long

    ServiceStatus = “”
    hSManager = OpenSCManager(ComputerName, SERVICES_ACTIVE_DATABASE, SC_MANAGER_ALL_ACCESS)
    If hSManager <> 0 Then
        hService = OpenService(hSManager, ServiceName, SERVICE_ALL_ACCESS)
        If hService <> 0 Then
            hServiceStatus = QueryServiceStatus(hService, ServiceStat)
            If hServiceStatus <> 0 Then
                Select Case ServiceStat.dwCurrentState
                Case SERVICE_STOPPED
                    ServiceStatus = “Stopped”
                Case SERVICE_START_PENDING
                    ServiceStatus = “Start Pending”
                Case SERVICE_STOP_PENDING
                    ServiceStatus = “Stop Pending”
                Case SERVICE_RUNNING
                    ServiceStatus = “Running”
                Case SERVICE_CONTINUE_PENDING
                    ServiceStatus = “Coninue Pending”
                Case SERVICE_PAUSE_PENDING
                    ServiceStatus = “Pause Pending”
                Case SERVICE_PAUSED
                    ServiceStatus = “Paused”
                End Select
            End If
            CloseServiceHandle hService
        End If
        CloseServiceHandle hSManager
    End If
End Function

Public Sub ServicePause(ComputerName As String, ServiceName As String)
    Dim ServiceStatus As SERVICE_STATUS
    Dim hSManager As Long
    Dim hService As Long
    Dim res As Long

    hSManager = OpenSCManager(ComputerName, SERVICES_ACTIVE_DATABASE, SC_MANAGER_ALL_ACCESS)
    If hSManager <> 0 Then
        hService = OpenService(hSManager, ServiceName, SERVICE_ALL_ACCESS)
        If hService <> 0 Then
            res = ControlService(hService, SERVICE_CONTROL_PAUSE, ServiceStatus)
            CloseServiceHandle hService
        End If
        CloseServiceHandle hSManager
    End If
End Sub

Public Sub ServiceStart(ComputerName As String, ServiceName As String)
    Dim ServiceStatus As SERVICE_STATUS
    Dim hSManager As Long
    Dim hService As Long
    Dim res As Long

    hSManager = OpenSCManager(ComputerName, SERVICES_ACTIVE_DATABASE, SC_MANAGER_ALL_ACCESS)
    If hSManager <> 0 Then
        hService = OpenService(hSManager, ServiceName, SERVICE_ALL_ACCESS)
        If hService <> 0 Then
            res = StartService(hService, 0, 0)
            CloseServiceHandle hService
        End If
        CloseServiceHandle hSManager
    End If
End Sub

Public Sub ServiceStop(ComputerName As String, ServiceName As String)
    Dim ServiceStatus As SERVICE_STATUS
    Dim hSManager As Long
    Dim hService As Long
    Dim res As Long

    hSManager = OpenSCManager(ComputerName, SERVICES_ACTIVE_DATABASE, SC_MANAGER_ALL_ACCESS)
    If hSManager <> 0 Then
        hService = OpenService(hSManager, ServiceName, SERVICE_ALL_ACCESS)
        If hService <> 0 Then
            res = ControlService(hService, SERVICE_CONTROL_STOP, ServiceStatus)
            CloseServiceHandle hService
        End If
        CloseServiceHandle hSManager
    End If
End Sub

Kembali ke form dan copikan juga syntak dibawah ini dengan memperhatikan letak dan nama komponen ke dalam sebuah form

Dim RetServiceName As String
Private Sub cmdCekStatus_Click()
If txtService.Text <> vbNullString Then
    If RetServiceName = “” Then
        Call AskParaMeter
    End If
     MsgBox “[ ” & RetServiceName & ” ] service status is : ” & ServiceStatus(“”, Trim(RetServiceName)), 64, Me.Caption
End If
End Sub

Private Sub cmdStartService_Click()
If txtService.Text <> vbNullString Then
    If RetServiceName = “” Then
        Call AskParaMeter
    End If
    ServiceStart “”, RetServiceName
    MsgBox “[ ” & RetServiceName & ” ] service run successfully”, 64, Me.Caption
End If
End Sub

Private Sub cmdStopService_Click()
If txtService.Text <> vbNullString Then
    If RetServiceName = “” Then
        Call AskParaMeter
    End If
    ServiceStop “”, RetServiceName
    MsgBox “[ ” & RetServiceName & ” ] service stopped successfully”, 64, Me.Caption
End If
End Sub

Public Sub AskParaMeter()
    RetServiceName = txtService.Text
End Sub

Jika telah tanggapan kemudian simpan dan RUN/F5. Kali ini admin akan mencoba Service dengan Service Name MySQL. Inputkan nama Service Name pada textBox diatas kemudian coba klik stop, maka service name MySQL pada jendela service akan berstatus Stopped begitu juga sebaliknya kalau klik command start maka service akan status Started. Untuk lebih jelasnya silahkan download sourcode pada LINK INI dan biar bermanfaat.
Author: 
    author
    No related post!